View stylesheet

<?xml version="1.0" encoding="UTF-8"?>
<!--
      Generate KML 2.0
  -->
<xsl:stylesheet xmlns="http://earth.google.com/kml/2.0"
xmlns:dd207="http://dd.eionet.europa.eu/namespace.jsp?ns_id=207"
xmlns:dd208="http://dd.eionet.europa.eu/namespace.jsp?ns_id=208"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
exclude-result-prefixes="dd207 dd208" version="1.0">
  <xsl:output method="xml" omit-xml-declaration="no"/>
  <xsl:template match="dd207:Station">
    <kml xmlns="http://earth.google.com/kml/2.0">
      <Document>
        <name>New Ozone stations</name>
        <description>Ozone stations in Europe</description>
        <Style id="station">
          <IconStyle>
            <scale>1.0</scale>
            <Icon>
              <href>root://icons/palette-4.png</href>
              <x>32</x>
              <y>128</y>
              <w>32</w>
              <h>32</h>
            </Icon>
          </IconStyle>
          <LabelStyle>
            <scale>1.0</scale>
          </LabelStyle>
        </Style>
        <xsl:apply-templates/>
      </Document>
    </kml>
  </xsl:template>
  <xsl:template match="dd207:Row">
    <Placemark>
      <name><xsl:value-of select="dd208:Local_station_code"/> - <xsl:value-of select="dd208:Station_name"/>
      </name>
      <description>
        <xsl:apply-templates/>
      </description>
      <open>0</open>
      <styleUrl>#station</styleUrl>
      <Point>
        <coordinates><xsl:value-of select="dd208:Longitude_decimal"/>,<xsl:value-of select="dd208:Latitude_decimal"/>,0</coordinates>
      </Point>
    </Placemark>
  </xsl:template>
  <xsl:template match="*"><xsl:value-of select="local-name()"/>: <xsl:value-of select="."/><xsl:text>&lt;br/&gt;</xsl:text></xsl:template>
</xsl:stylesheet>