View stylesheet

<?xml version="1.0" encoding="UTF-8"?>
<!--
      Generate KML 2.0
  -->
<xsl:stylesheet xmlns="http://earth.google.com/kml/2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="xml" indent="yes" omit-xml-declaration="no"/>


  <xsl:template match="/">
    <kml xmlns="http://earth.google.com/kml/2.0">
      <Document>
        <name>UWWT Delivery</name>
        <description>Agglomerations, UWWTPs and DischargePoints in Europe</description>
        <Style id="agglomeration">
          <IconStyle>
            <scale>1.0</scale>
            <color>ff0000ff</color>
          </IconStyle>
          <LabelStyle>
            <scale>0.8</scale>
            <color>ff8080ff</color>
          </LabelStyle>
        </Style>
        <Style id="uwwtp">
          <IconStyle>
            <scale>1.0</scale>
            <color>ff00ff00</color>
          </IconStyle>
          <LabelStyle>
            <scale>0.8</scale>
            <color>ff80ff80</color>
          </LabelStyle>
        </Style>
        <Style id="dischargepoint">
          <IconStyle>
            <scale>1.0</scale>
            <color>ffff8080</color>
          </IconStyle>
          <LabelStyle>
            <scale>0.8</scale>
            <color>ffff8080</color>
          </LabelStyle>
        </Style>

        <xsl:apply-templates/>
      </Document>
    </kml>
  </xsl:template>

  <xsl:template match="UWWTD_Data">
    <xsl:apply-templates/>
  </xsl:template>

  <xsl:template match="UWWTD_Report">
    <Folder>
      <name>Report</name>
      <open>1</open>
      <Folder>
        <name>Agglomerations</name>
    <xsl:apply-templates select="Agglomerations/Agglomeration">
      <xsl:sort select="aggName"/>
    </xsl:apply-templates>
      </Folder>
      <Folder>
        <name>UWWTPs</name>
    <xsl:apply-templates select="UWWTPs/UWWTP">
      <xsl:sort select="uwwName"/>
    </xsl:apply-templates>
      </Folder>
      <Folder>
        <name>Discharge Points</name>
    <xsl:apply-templates select="DischargePoints/DischargePoint">
      <xsl:sort select="dcpName"/>
    </xsl:apply-templates>
      </Folder>
    </Folder>
  </xsl:template>

  <xsl:template match="Agglomeration">
    <Placemark>
      <name>Agglomeration: <xsl:value-of select="aggName"/></name>
      <!--
      <description>
        <xsl:apply-templates/>
      </description>
      -->
      <open>0</open>
      <styleUrl>#agglomeration</styleUrl>
      <Point>
        <coordinates><xsl:value-of select="aggLongitude"/>,<xsl:value-of select="aggLatitude"/></coordinates>
      </Point>
    </Placemark>
  </xsl:template>

  <xsl:template match="UWWTP">
    <Placemark>
      <name>UWWTP: <xsl:value-of select="uwwName"/></name>
      <!--
      <description>
        <xsl:apply-templates/>
      </description>
      -->
      <open>0</open>
      <styleUrl>#uwwtp</styleUrl>
      <Point>
        <coordinates><xsl:value-of select="uwwLongitude"/>,<xsl:value-of select="uwwLatitude"/></coordinates>
      </Point>
    </Placemark>
  </xsl:template>

  <xsl:template match="DischargePoint">
    <Placemark>
      <name>Discharge Point: <xsl:value-of select="dcpName"/></name>
      <!--
      <description>
        <xsl:apply-templates/>
      </description>
      -->
      <open>0</open>
      <styleUrl>#dischargepoint</styleUrl>
      <Point>
        <coordinates><xsl:value-of select="dcpLongitude"/>,<xsl:value-of select="dcpLatitude"/></coordinates>
      </Point>
    </Placemark>
  </xsl:template>

  <!--
  <xsl:template match="*"><xsl:value-of select="local-name()"/>: <xsl:value-of select="."/><xsl:text>&lt;br/&gt;</xsl:text></xsl:template>
  -->

  <xsl:template match="*"/>
</xsl:stylesheet>