Eionet
Conversion and Quality Assessment Service
View stylesheet
| XML schema |
http://water.eionet.europa.eu/schemas/dir200060ec/GroundWaterMonitoringStations_3p0.xsd
|
|---|---|
| Output type | HTML |
| Description | HTML Factsheet |
| XSL file | GroundWaterMonitoringStations_3p0.xsl (Last modified: 22 Oct 2009 20:43 ) |
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:wf="http://water.eionet.europa.eu/schemas/dir200060ec">
<xsl:output omit-xml-declaration="yes" encoding="UTF-8"/>
<!-- Created by Yvonne Walker WRc plc 21/04/2005 for WFD 2005 Reporting -->
<!-- History
Amended 09/03/2007 YGW
Table of Contents: Amended to display Groundwater (not Surface water)
Station Details: Water body location changed to display the correct value (was MS_CD)
Amended 27/03/2007 YGW
Additional requirements if station in drinking water abstraction areas: changed to ADDITIONAL_REQS (was OTHER_NETWORKS)
Amended 05/08/2009 Jon Maidens, Atkins
namespace changed / DIST_CD changed to EURBDcode / ASSOC_DOC_REF changed to METADATA
-->
<xsl:param name="code">we</xsl:param>
<xsl:param name="flagpath">http://wise2.jrc.it/wfdview/images/flags/</xsl:param>
<xsl:template match="/">
<html>
<head>
<title>WFD Article 8 Submission Report - Groundwater Monitoring Stations</title>
<style type="text/css">
h1 {font-size: 30pt; font-family: Arial, Helvetica, sans-serif; color:#003399; font-weight : bold;}
h2 {font-size: 20pt;font-family: Arial, Helvetica, sans-serif;color : #003399;font-weight : bold;}
h3 {font-size: 14pt;font-family: Arial, Helvetica, sans-serif;color : #003399;font-weight : bold;}
h4 {font-size: 12pt;font-family: Arial, Helvetica, sans-serif;color : #003399;font-weight : bold;text-decoration : underline;}
h5 {font-size: 10pt;font-family: Arial, Helvetica, sans-serif;color : #003399;font-weight : bold;text-decoration : underline;}
h6 {font-size: 10pt;font-family: Arial, Helvetica, sans-serif;color : #003399;font-weight : bold;font-style:italic; text-decoration : underline;}
table {font-size: 10pt;font-family: Arial, Helvetica, sans-serif;color : #000000;}
td.table_header_left {font-size: 10pt;font-family: Arial, Helvetica, sans-serif; color : #000000;font-weight : bold; text-align : left;background-color : #DBDBDB;}
td.table_data {font-size: 10pt;font-family: Arial, Helvetica, sans-serif; color : #000000; text-align : left;}
th {font-size: 10pt;font-family: Arial, Helvetica, sans-serif; color : #000000;font-weight : bold; text-align : left;background-color : #DBDBDB;vertical-align : top}
td {font-size: 10pt;font-family: Arial, Helvetica, sans-serif; color : #000000; text-align : left;vertical-align : top;}
DIV.Section {page-break-after : always;}
.msg1 {font-family:Arial, Helvetica, sans-serif; font-size :8pt; font-weight :bold; color:#003399;}
.msg {font-family:Arial, Helvetica, sans-serif; font-size :10pt; font-style:italic; color:#000000;}
.indent1 {margin-left: 10px}
.indent2 {margin-left: 20px}
.indent3 {margin-left: 30px}
.indent4 {margin-left: 40px}
</style>
</head>
<body>
<xsl:apply-templates/>
</body>
</html>
</xsl:template>
<xsl:template match="wf:GROUNDWATERMONITORINGSTATIONS">
<table>
<tbody>
<tr>
<td valign="top" align="left">
<h1>
WFD Article 8 Groundwater Monitoring Stations For
<xsl:call-template name="Country">
<xsl:with-param name="MS" select="wf:C_CD"/>
</xsl:call-template>
</h1>
<div class="Section">
<h1>RBD: <xsl:value-of select="wf:NAME"></xsl:value-of> (<xsl:value-of select="wf:EURBDCode"/>)
</h1>
<table>
<tbody>
<tr>
<th width="250">European code*</th>
<td ><xsl:value-of select="wf:EURBDCode"/></td>
</tr>
<tr>
<th>Name*</th>
<td ><xsl:value-of select="wf:NAME"/></td>
</tr>
<tr>
<th>Reporting level*</th>
<td ><xsl:call-template name="ReportingLevel"><xsl:with-param name="Param" select="wf:REPORTING_LEVEL"/></xsl:call-template></td>
</tr>
<tr>
<th>Reporting level description:</th>
<td ><xsl:value-of select="wf:REPORTING_LEVEL_DESCRIPTION"/></td>
</tr>
<tr>
<th>Metadata:</th>
<td >
<xsl:value-of select="wf:METADATA"/>
</td>
</tr>
<tr>
<th>URL to further information:</th>
<td >
<a>
<xsl:attribute name="href"><xsl:value-of select="wf:URL"/></xsl:attribute>
<xsl:value-of select="wf:URL"/>
</a>
</td>
</tr>
</tbody>
</table>
<h4>XML file details</h4>
<table>
<tbody>
<tr>
<th width="250">XML file creation date</th>
<td><xsl:value-of select="@CreationDate"/></td>
</tr>
<tr>
<th>Created by</th>
<td><xsl:value-of select="@Creator"/></td>
</tr>
<tr>
<th>Email</th>
<td><xsl:value-of select="@Email"/></td>
</tr>
<tr>
<th>Description</th>
<td><xsl:value-of select="@Description"/></td>
</tr>
<tr>
<th>Generated By</th>
<td><xsl:value-of select="@GeneratedBy"/></td>
</tr>
<tr>
<th>Classification Code</th>
<td><xsl:call-template name="ClassificationCode"><xsl:with-param name="Param" select="@MD_ClassificationCode"/></xsl:call-template></td>
</tr>
</tbody>
</table>
</div>
<!-- Do the table of contents -->
<div class="Section">
<h2><a name="contents"></a>Contents</h2>
<xsl:call-template name="TableOfContents"/>
</div>
<!-- Groundwater Monitoring Stations -->
<div class="Section">
<h2>
<a name="1"></a>1. Groundwater Monitoring Stations Overview
</h2>
<xsl:call-template name="StationOverview"/>
</div>
<div class="Section">
<h2>
<a name="2"></a>2. Groundwater Monitoring Stations Details
</h2>
<xsl:call-template name="StationDetail"/>
</div>
</td>
</tr>
</tbody>
</table>
</xsl:template>
<xsl:template name="StationOverview">
<p><span class="msg">This section provides a summary of the groundwater monitoring stations (quantitative and chemical surveillance/operational). Click on the station number to view to the detail for that station</span></p>
<table>
<tbody>
<tr>
<th>No.</th>
<th>EU Code*</th>
<th>MS Code*</th>
<th>Longitude*</th>
<th>Latitude*</th>
<th>Name</th>
<th>Waterbody Location*</th>
<th>Type*</th>
<th>Quantitative*</th>
<th>Chemical Surveillance*</th>
<th>Chemical Operational*</th>
<th>No. of Sub-sites*</th>
<th>Depth</th>
<th>Monitoring</th>
<th>Drinking Water</th>
<th>Industrial Supply</th>
<th>Irrigation</th>
<th>Other purposes</th>
<th>Programmes*</th>
</tr>
<xsl:for-each select="wf:GROUNDWATERMONITORINGSTATION">
<tr>
<td align="right"><a><xsl:attribute name="href">#GMS<xsl:value-of select="position()"/></xsl:attribute><xsl:value-of select="position()"/></a></td>
<td ><xsl:value-of select="wf:EU_CD"/></td>
<td ><xsl:value-of select="wf:MS_CD"/></td>
<td ><xsl:value-of select="wf:LON"/></td>
<td ><xsl:value-of select="wf:LAT"/></td>
<td ><xsl:value-of select="wf:NAME"/></td>
<td ><xsl:value-of select="wf:WB_LOCATION"/></td>
<td ><xsl:call-template name="WellOrSpring"><xsl:with-param name="Param" select="wf:WELL_OR_SPRING"/></xsl:call-template></td>
<td ><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:QUANTITATIVE"/></xsl:call-template></td>
<td ><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:CHEM_SURVEIL"/></xsl:call-template></td>
<td ><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:CHEM_OPERAT"/></xsl:call-template></td>
<td ><xsl:value-of select="wf:NO_SUBSITES"/></td>
<td ><xsl:call-template name="Depth"><xsl:with-param name="Param" select="wf:DEPTH"/></xsl:call-template></td>
<td ><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:MONITORING"/></xsl:call-template></td>
<td ><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:DRINK_WATER"/></xsl:call-template></td>
<td ><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:IND_SUPPLY"/></xsl:call-template></td>
<td ><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:IRRIGATION"/></xsl:call-template></td>
<td ><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:OTHER_SUPPLY"/></xsl:call-template></td>
<td><xsl:for-each select="wf:PROGRAMMES/wf:PROGRAMME">
<xsl:if test="position() > 1">
<br/>
</xsl:if>
<xsl:value-of select="wf:PROGRAMME_CD"/>
</xsl:for-each>
</td>
</tr>
</xsl:for-each>
</tbody>
</table>
</xsl:template>
<xsl:template name="StationDetail">
<p><span class="msg">This section provides the details for the groundwater monitoring stations</span></p>
<xsl:for-each select="wf:GROUNDWATERMONITORINGSTATION">
<div class="Section">
<h3><a><xsl:attribute name="name">#GMS<xsl:value-of select="position()"/></xsl:attribute><xsl:value-of select="position()"/></a> Monitoring Station <xsl:value-of select="wf:EU_CD"/> - <xsl:value-of select="wf:NAME"/></h3>
<table>
<tbody>
<tr>
<th width="250">Unique EU code for the station*</th>
<td><xsl:value-of select="wf:EU_CD"/></td>
</tr>
<tr>
<th width="250">Unique MS code for the station*</th>
<td><xsl:value-of select="wf:MS_CD"/></td>
</tr>
<tr>
<th width="250">Location (Lon/Lat)*</th>
<td><xsl:value-of select="wf:LON"/>, <xsl:value-of select="wf:LAT"/></td>
</tr>
<tr>
<th width="250">Name</th>
<td><xsl:value-of select="wf:NAME"/></td>
</tr>
<tr>
<th width="250">EU code of the groundwater body which the station is physically located on or near. *</th>
<td><xsl:value-of select="wf:WB_LOCATION"/></td>
</tr>
<tr>
<th width="250">Type of station.*</th>
<td><xsl:call-template name="WellOrSpring"><xsl:with-param name="Param" select="wf:WELL_OR_SPRING"/></xsl:call-template></td>
</tr>
<tr>
<th width="250">Station is used for quantitative monitoring.*</th>
<td><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:QUANTITATIVE"/></xsl:call-template></td>
</tr>
<tr>
<th width="250">Station is used for chemical surveillance monitoring.*</th>
<td><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:CHEM_SURVEIL"/></xsl:call-template></td>
</tr>
<tr>
<th width="250">Station is used for chemical operational monitoring.*</th>
<td><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:CHEM_OPERAT"/></xsl:call-template></td>
</tr>
<tr>
<th width="250">Number of subsites normally associated with this station.*</th>
<td><xsl:value-of select="wf:NO_SUBSITES"/></td>
</tr>
<tr>
<th width="250">Monitoring depth.*</th>
<td><xsl:call-template name="Depth"><xsl:with-param name="Param" select="wf:DEPTH"/></xsl:call-template></td>
</tr>
<tr>
<th width="250">Site is used for monitoring of groundwater status</th>
<td><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:MONITORING"/></xsl:call-template></td>
</tr>
<tr>
<th width="250">Site is used for the abstraction of drinking water</th>
<td><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:DRINK_WATER"/></xsl:call-template></td>
</tr>
<tr>
<th width="250">Additional requirements if station is located in a drinking water abstraction site</th>
<td><xsl:value-of select="wf:ADDITIONAL_REQS"/></td>
</tr>
<tr>
<th width="250">Site is used for industrial supply</th>
<td><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:IND_SUPPLY"/></xsl:call-template></td>
</tr>
<tr>
<th width="250">Site is used for irrigation</th>
<td><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:IRRIGATION"/></xsl:call-template></td>
</tr>
<tr>
<th width="250">Site is used for other purposes</th>
<td><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:OTHER_SUPPLY"/></xsl:call-template></td>
</tr>
<tr>
<th width="250">Brief description of any networks that this station is a part of</th>
<td><xsl:value-of select="wf:OTHER_NETWORKS"/></td>
</tr>
<tr>
<th width="250">Hyperlink or reference to associated reference statement or file</th>
<td ><xsl:value-of select="wf:METADATA"/></td>
</tr>
<tr>
<th width="250">URL to further information:</th>
<td ><a><xsl:attribute name="href"><xsl:value-of select="wf:URL"/></xsl:attribute><xsl:value-of select="wf:URL"/></a></td>
</tr>
</tbody>
</table>
<!-- now do the other networks -->
<h4>International Networks</h4>
<p><span class="msg">International networks that this station is part of, if any</span></p>
<table>
<tbody>
<tr>
<th>Name of the network</th>
<th>Unique code for the station in this network</th>
</tr>
<xsl:for-each select="wf:INTER_NETWORKS/wf:INTER_NETWORK">
<tr>
<td><xsl:value-of select="wf:NAME"/></td>
<td><xsl:value-of select="wf:SITE_CD"/></td>
</tr>
</xsl:for-each>
</tbody>
</table>
<!-- now the programme details -->
<h4>Programmes</h4>
<p><span class="msg">This section describes the Article 8 programmes that the station is part of. The stations are linked to the programme using the code of the programme. A station may be part of more than one programme</span></p>
<xsl:apply-templates select="wf:PROGRAMMES/wf:PROGRAMME"/>
</div>
</xsl:for-each>
</xsl:template>
<xsl:template match="wf:PROGRAMMES/wf:PROGRAMME">
<h5>Programme: <xsl:value-of select="wf:PROGRAMME_CD"/></h5>
<table>
<tbody>
<tr>
<th width="250">EU code for programme.</th>
<td><xsl:value-of select="wf:PROGRAMME_CD"/></td>
</tr>
<tr>
<th width="250"> Waterbodies monitored by this station</th>
<td><xsl:for-each select="wf:ASSOC_WB/wf:WB_CD">
<xsl:if test="position() > 1">, </xsl:if>
<xsl:value-of select="."/>
</xsl:for-each>
</td>
</tr>
</tbody>
</table>
<h6>Parameters measured at the station for this programme </h6>
<p><span class="msg">If this section is empty, then it is assumed that all parameters defined in the programme are monitored for each associated waterbody. </span></p>
<table>
<tbody>
<tr>
<th>Parameter Code*</th>
<th>How measured</th>
<th>Quantitative</th>
<th>Chemical Surveillence</th>
<th>Chemical Operational</th>
<th>Subsites</th>
<th>Frequency</th>
<th>Cycle</th>
<th>Cycle description</th>
<th>Reason for deviation </th>
<th>Waterbodies</th>
</tr>
<xsl:for-each select="wf:PARAMETERS/wf:PARAMETER">
<tr>
<td ><xsl:value-of select="wf:PARAMETER_CD"/></td>
<td ><xsl:value-of select="wf:MEASURED_AS"/></td>
<td><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:QUANTITATIVE"/></xsl:call-template></td>
<td><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:CHEM_SURVEIL"/></xsl:call-template></td>
<td><xsl:call-template name="YesNoUnknown"><xsl:with-param name="Param" select="wf:CHEM_OPERAT"/></xsl:call-template></td>
<td><xsl:call-template name="SubsiteType"><xsl:with-param name="Param" select="wf:SUBSITES"/></xsl:call-template></td>
<td><xsl:value-of select="wf:FREQUENCY"/></td>
<td><xsl:value-of select="wf:CYCLE"/></td>
<td><xsl:value-of select="wf:CYCLE_DESCRIPTION"/></td>
<td ><xsl:value-of select="wf:REASON"/></td>
<td><xsl:for-each select="wf:ASSOC_WB/wf:WB_CD">
<xsl:if test="position() > 1">, </xsl:if>
<xsl:value-of select="."/>
</xsl:for-each>
</td>
</tr>
</xsl:for-each>
</tbody>
</table>
</xsl:template>
<xsl:template name="TableOfContents">
<span class="indent1"><a href="#1">1. Groundwater Monitoring Stations Overview</a></span><br/>
<span class="indent1"><a href="#2">2. Groundwater Monitoring Stations Details</a></span><br/>
</xsl:template>
<!-- Country implementation -->
<xsl:template name="Country">
<xsl:param name="MS"/>
<xsl:choose>
<xsl:when test="$MS='AT'">Austria</xsl:when>
<xsl:when test="$MS='BE'">Belgium</xsl:when>
<xsl:when test="$MS='BG'">Bulgaria</xsl:when>
<xsl:when test="$MS='CH'">Switzerland</xsl:when>
<xsl:when test="$MS='CY'">Cyprus</xsl:when>
<xsl:when test="$MS='CZ'">Czech Republic</xsl:when>
<xsl:when test="$MS='DE'">Germany</xsl:when>
<xsl:when test="$MS='DK'">Denmark</xsl:when>
<xsl:when test="$MS='EE'">Estonia</xsl:when>
<xsl:when test="$MS='ES'">Spain</xsl:when>
<xsl:when test="$MS='FI'">Finland</xsl:when>
<xsl:when test="$MS='FR'">France</xsl:when>
<xsl:when test="$MS='GR'">Greece</xsl:when>
<xsl:when test="$MS='HU'">Hungary</xsl:when>
<xsl:when test="$MS='IE'">Ireland</xsl:when>
<xsl:when test="$MS='IS'">Iceland</xsl:when>
<xsl:when test="$MS='IT'">Italy</xsl:when>
<xsl:when test="$MS='LT'">Lithuania</xsl:when>
<xsl:when test="$MS='LU'">Luxembourg</xsl:when>
<xsl:when test="$MS='LV'">Latvia</xsl:when>
<xsl:when test="$MS='MT'">Malta</xsl:when>
<xsl:when test="$MS='NL'">The Netherlands</xsl:when>
<xsl:when test="$MS='NO'">Norway</xsl:when>
<xsl:when test="$MS='PL'">Poland</xsl:when>
<xsl:when test="$MS='PT'">Portugal</xsl:when>
<xsl:when test="$MS='RO'">Romania</xsl:when>
<xsl:when test="$MS='SE'">Sweden</xsl:when>
<xsl:when test="$MS='SI'">Slovenia</xsl:when>
<xsl:when test="$MS='SK'">Slovakia</xsl:when>
<xsl:when test="$MS='TR'">Turkey</xsl:when>
<xsl:when test="$MS='UK'">United Kingdom</xsl:when>
</xsl:choose>
</xsl:template>
<!-- Classification code implementation -->
<xsl:template name="ClassificationCode">
<xsl:param name="Param"/>
<xsl:choose>
<xsl:when test="$Param = '001'">Unclassified - available for general circulation</xsl:when>
<xsl:when test="$Param = '003'">Confidential - available for EC reporting only</xsl:when>
</xsl:choose>
</xsl:template>
<!-- YesNoUnknown implementation -->
<xsl:template name="YesNoUnknown">
<xsl:param name="Param"/>
<xsl:choose>
<xsl:when test="$Param = 'Y'">Yes</xsl:when>
<xsl:when test="$Param = 'N'">No</xsl:when>
<xsl:when test="$Param = 'U'">Unknown</xsl:when>
<xsl:when test="$Param = 'NA'">Not Applicable</xsl:when>
</xsl:choose>
</xsl:template>
<!-- WaterBodyCategory implementation -->
<xsl:template name="WaterBodyCategory">
<xsl:param name="Param"/>
<xsl:choose>
<xsl:when test="$Param = 'RW'">River</xsl:when>
<xsl:when test="$Param = 'LW'">Lake</xsl:when>
<xsl:when test="$Param = 'TW'">Transitional</xsl:when>
<xsl:when test="$Param = 'CW'">Coastal</xsl:when>
</xsl:choose>
</xsl:template>
<!-- Reporting Level implementation -->
<xsl:template name="ReportingLevel">
<xsl:param name="Param"/>
<xsl:choose>
<xsl:when test="$Param = 'I'">International RBD</xsl:when>
<xsl:when test="$Param = 'N'">National part of an international RBD</xsl:when>
<xsl:when test="$Param = 'R'">National RBD</xsl:when>
<xsl:when test="$Param = 'S'">Regional part or sub-unit of RBD</xsl:when>
</xsl:choose>
</xsl:template>
<!-- Programme Level implementation -->
<xsl:template name="ProgrammeLevel">
<xsl:param name="Param"/>
<xsl:choose>
<xsl:when test="$Param = 'I'">International</xsl:when>
<xsl:when test="$Param = 'N'">National</xsl:when>
<xsl:when test="$Param = 'R'">RBD</xsl:when>
</xsl:choose>
</xsl:template>
<!-- Incident type implementation -->
<xsl:template name="IncidentType">
<xsl:param name="Param"/>
<xsl:choose>
<xsl:when test="$Param = 'E'">Unknown exceedence</xsl:when>
<xsl:when test="$Param = 'F'">Failure of objectives</xsl:when>
<xsl:when test="$Param = 'R'">Incident response</xsl:when>
<xsl:when test="$Param = 'O'">Other</xsl:when>
</xsl:choose>
</xsl:template>
<!-- Subsite type implementation -->
<xsl:template name="SubsiteType">
<xsl:param name="Param"/>
<xsl:choose>
<xsl:when test="$Param = 'A'">Area</xsl:when>
<xsl:when test="$Param = 'T'">Transect</xsl:when>
<xsl:when test="$Param = 'M'">Multipoint</xsl:when>
<xsl:when test="$Param = 'N'">Not applicable/None</xsl:when>
</xsl:choose>
</xsl:template>
<!-- Well or springtype implementation -->
<xsl:template name="WellOrSpring">
<xsl:param name="Param"/>
<xsl:choose>
<xsl:when test="$Param = 'W'">Well</xsl:when>
<xsl:when test="$Param = 'S'">Spring</xsl:when>
<xsl:when test="$Param = 'O'">Other</xsl:when>
</xsl:choose>
</xsl:template>
<!-- Depth type implementation -->
<xsl:template name="Depth">
<xsl:param name="Param"/>
<xsl:choose>
<xsl:when test="$Param = 'U'">Upper</xsl:when>
<xsl:when test="$Param = 'M'">Middle</xsl:when>
<xsl:when test="$Param = 'L'">Lower</xsl:when>
<xsl:when test="$Param = 'A'">Mixed/All</xsl:when>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>