View stylesheet

XML schemas http://water.eionet.europa.eu/schemas/dir200060ec/SurfaceWaterMonitoringStations.xsd
Output type HTML
Description HTML factsheet
XSL file SurfaceWaterMonitoringStations.xsl (Last modified: 12 Dec 2007 16:50 )
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:wf="http://wise.jrc.cec.eu.int" version="1.0">
  <xsl:output omit-xml-declaration="yes" encoding="UTF-8"/>
  <!-- Created by Yvonne Walker WRc plc 21/04/2005 for WFD 2005 Reporting -->
  <!-- Amendments History
	     
	     Amended 09/03/2007 YGW
	     Station Details:		Water body location changed to display the correct value (was MS_CD)
	     
	     -->
  <xsl:param name="code">we</xsl:param>
  <xsl:template match="/">
    <html>
      <head>
        <title>WFD Article 8 2007 Submission Report - Surface Water Monitoring Stations</title>
        <style type="text/css">

h1						{font-size: 30pt; font-family: Arial, Helvetica, sans-serif; color:#003399; font-weight : bold;}
h2						{font-size: 20pt;font-family: Arial, Helvetica, sans-serif;color : #003399;font-weight : bold;}
h3						{font-size: 14pt;font-family: Arial, Helvetica, sans-serif;color : #003399;font-weight : bold;}
h4						{font-size: 12pt;font-family: Arial, Helvetica, sans-serif;color : #003399;font-weight : bold;text-decoration : underline;}
h5						{font-size: 10pt;font-family: Arial, Helvetica, sans-serif;color : #003399;font-weight : bold;text-decoration : underline;}
h6						{font-size: 10pt;font-family: Arial, Helvetica, sans-serif;color : #003399;font-weight : bold;font-style:italic; text-decoration : underline;}

table					{font-size: 10pt;font-family: Arial, Helvetica, sans-serif;color : #000000;}

td.table_header_left		{font-size: 10pt;font-family: Arial, Helvetica, sans-serif; color : #000000;font-weight : bold; text-align : left;background-color : #DBDBDB;}
td.table_data			{font-size: 10pt;font-family: Arial, Helvetica, sans-serif; color : #000000; text-align : left;}
th						{font-size: 10pt;font-family: Arial, Helvetica, sans-serif; color : #000000;font-weight : bold; text-align : left;background-color : #DBDBDB;vertical-align : top}
td						{font-size: 10pt;font-family: Arial, Helvetica, sans-serif; color : #000000; text-align : left;vertical-align : top;}

DIV.Section 				{page-break-after : always;}

.msg1					{font-family:Arial, Helvetica, sans-serif; font-size :8pt; font-weight :bold; color:#003399;}
.msg					{font-family:Arial, Helvetica, sans-serif; font-size :10pt; font-style:italic; color:#000000;}

.indent1					{margin-left: 10px}
.indent2					{margin-left: 20px}
.indent3					{margin-left: 30px}
.indent4					{margin-left: 40px}

				</style>
      </head>
      <body>
        <xsl:apply-templates/>
      </body>
    </html>
  </xsl:template>
  <xsl:template match="wf:SURFACEWATERMONITORINGSTATIONS">
    <table>
      <tbody>
        <tr>
          <td valign="top" align="left">
                <h1>
			WFD Article 8 Surface Water Monitoring Stations For
			<xsl:call-template name="Country"><xsl:with-param name="MS" select="wf:C_CD"/></xsl:call-template>
		</h1>
            <div class="Section">
              <h1>RBD: <xsl:value-of select="wf:NAME"/> (<xsl:value-of select="wf:DIST_CD"/>)
					</h1>
              <table>
                <tbody>
                  <tr>
                    <th width="250">European code*</th>
                    <td>
                      <xsl:value-of select="wf:DIST_CD"/>
                    </td>
                  </tr>
                  <tr>
                    <th>Name*</th>
                    <td>
                      <xsl:value-of select="wf:NAME"/>
                    </td>
                  </tr>
                  <tr>
                    <th>Reporting level*</th>
                    <td>
                      <xsl:call-template name="ReportingLevel">
                        <xsl:with-param name="Param" select="wf:REPORTING_LEVEL"/>
                      </xsl:call-template>
                    </td>
                  </tr>
                  <tr>
                    <th>Reporting level description:</th>
                    <td>
                      <xsl:value-of select="wf:REPORTING_LEVEL_DESCRIPTION"/>
                    </td>
                  </tr>
                  <tr>
                    <th>Metadata:</th>
                    <td>
                      <xsl:value-of select="wf:METADATA"/>
                    </td>
                  </tr>
                  <tr>
                    <th>URL to further information:</th>
                    <td>
                      <a>
                        <xsl:attribute name="href">
                          <xsl:value-of select="wf:URL"/>
                        </xsl:attribute>
                        <xsl:value-of select="wf:URL"/>
                      </a>
                    </td>
                  </tr>
                </tbody>
              </table>
              <h4>XML file details</h4>
              <table>
                <tbody>
                  <tr>
                    <th width="250">XML file creation date</th>
                    <td>
                      <xsl:value-of select="@CreationDate"/>
                    </td>
                  </tr>
                  <tr>
                    <th>Created by</th>
                    <td>
                      <xsl:value-of select="@Creator"/>
                    </td>
                  </tr>
                  <tr>
                    <th>Email</th>
                    <td>
                      <xsl:value-of select="@Email"/>
                    </td>
                  </tr>
                  <tr>
                    <th>Description</th>
                    <td>
                      <xsl:value-of select="@Description"/>
                    </td>
                  </tr>
                  <tr>
                    <th>Generated By</th>
                    <td>
                      <xsl:value-of select="@GeneratedBy"/>
                    </td>
                  </tr>
                  <tr>
                    <th>Classification Code</th>
                    <td>
                      <xsl:call-template name="ClassificationCode">
                        <xsl:with-param name="Param" select="@MD_ClassificationCode"/>
                      </xsl:call-template>
                    </td>
                  </tr>
                </tbody>
              </table>
            </div>
            <!-- Do the table of contents -->
            <div class="Section">
              <h2><a name="contents"/>Contents</h2>
              <xsl:call-template name="TableOfContents"/>
            </div>
            <!-- Surface Water Monitoring Stations -->
            <div class="Section">
              <h2><a name="1"/>1. Surface Water Monitoring Stations Overview 						
					</h2>
              <xsl:call-template name="StationOverview"/>
            </div>
            <div class="Section">
              <h2><a name="2"/>2. Surface Water Monitoring Stations Details 						
					</h2>
              <xsl:call-template name="StationDetail"/>
            </div>
          </td>
        </tr>
      </tbody>
    </table>
  </xsl:template>
  <xsl:template name="StationOverview">
    <p>
      <span class="msg">This section provides a summary of the surface water monitoring stations (surveillance and operational). Click on the station number to view to the detail for that station</span>
    </p>
    <table>
      <tbody>
        <tr>
          <th>No.</th>
          <th>EU Code*</th>
          <th>MS Code*</th>
          <th>Longitude*</th>
          <th>Latitude*</th>
          <th>Name</th>
          <th>Waterbody Location*</th>
          <th>Surveillance*</th>
          <th>Operational*</th>
          <th>No. of Sub-sites*</th>
          <th>Drinking Water Abstraction*</th>
          <th>Intercalibration Site*</th>
          <th>Reference Site*</th>
          <th>Other Networks</th>
          <th>Programmes*</th>
        </tr>
        <xsl:for-each select="wf:SURFACEWATERMONITORINGSTATION">
          <tr>
            <td align="right">
              <a>
                <xsl:attribute name="href">#SMS<xsl:value-of select="position()"/></xsl:attribute>
                <xsl:value-of select="position()"/>
              </a>
            </td>
            <td>
              <xsl:value-of select="wf:EU_CD"/>
            </td>
            <td>
              <xsl:value-of select="wf:MS_CD"/>
            </td>
            <td>
              <xsl:value-of select="wf:LON"/>
            </td>
            <td>
              <xsl:value-of select="wf:LAT"/>
            </td>
            <td>
              <xsl:value-of select="wf:NAME"/>
            </td>
            <td>
              <xsl:value-of select="wf:WB_LOCATION"/>
            </td>
            <td>
              <xsl:call-template name="YesNoUnknown">
                <xsl:with-param name="Param" select="wf:SURVEIL"/>
              </xsl:call-template>
            </td>
            <td>
              <xsl:call-template name="YesNoUnknown">
                <xsl:with-param name="Param" select="wf:OPERAT"/>
              </xsl:call-template>
            </td>
            <td>
              <xsl:value-of select="wf:NO_SUBSITES"/>
            </td>
            <td>
              <xsl:call-template name="YesNoUnknown">
                <xsl:with-param name="Param" select="wf:DRINK_WATER"/>
              </xsl:call-template>
            </td>
            <td>
              <xsl:call-template name="YesNoUnknown">
                <xsl:with-param name="Param" select="wf:INTERCAL_SITE"/>
              </xsl:call-template>
            </td>
            <td>
              <xsl:call-template name="YesNoUnknown">
                <xsl:with-param name="Param" select="wf:REFERENCE_SITE"/>
              </xsl:call-template>
            </td>
            <td>
              <xsl:value-of select="wf:OTHER_NETWORKS"/>
            </td>
            <td>
              <xsl:for-each select="wf:PROGRAMMES/wf:PROGRAMME">
                <xsl:if test="position() &gt; 1">
                  <br/>
                </xsl:if>
                <xsl:value-of select="wf:SUB_CD"/>
              </xsl:for-each>
            </td>
          </tr>
        </xsl:for-each>
      </tbody>
    </table>
  </xsl:template>
  <xsl:template name="StationDetail">
    <p>
      <span class="msg">This section provides the details for the surface water monitoring stations</span>
    </p>
    <xsl:for-each select="wf:SURFACEWATERMONITORINGSTATION">
      <div class="Section">
        <h3><a><xsl:attribute name="name">#SMS<xsl:value-of select="position()"/></xsl:attribute><xsl:value-of select="position()"/></a> Monitoring Station <xsl:value-of select="wf:EU_CD"/> - <xsl:value-of select="wf:NAME"/></h3>
        <table>
          <tbody>
            <tr>
              <th width="250">Unique EU code for the station*</th>
              <td>
                <xsl:value-of select="wf:EU_CD"/>
              </td>
            </tr>
            <tr>
              <th width="250">Unique MS code for the station*</th>
              <td>
                <xsl:value-of select="wf:MS_CD"/>
              </td>
            </tr>
            <tr>
              <th width="250">Location (Lon/Lat)*</th>
              <td><xsl:value-of select="wf:LON"/>, <xsl:value-of select="wf:LAT"/></td>
            </tr>
            <tr>
              <th width="250">Name</th>
              <td>
                <xsl:value-of select="wf:NAME"/>
              </td>
            </tr>
            <tr>
              <th width="250">EU code of the surface water body which the station is physically located on or near. *</th>
              <td>
                <xsl:value-of select="wf:WB_LOCATION"/>
              </td>
            </tr>
            <tr>
              <th width="250">Station is used for surveillance monitoring.*</th>
              <td>
                <xsl:call-template name="YesNoUnknown">
                  <xsl:with-param name="Param" select="wf:SURVEIL"/>
                </xsl:call-template>
              </td>
            </tr>
            <tr>
              <th width="250">Station is used for operational monitoring.*</th>
              <td>
                <xsl:call-template name="YesNoUnknown">
                  <xsl:with-param name="Param" select="wf:OPERAT"/>
                </xsl:call-template>
              </td>
            </tr>
            <tr>
              <th width="250">Number of subsites normally associated with this station.*</th>
              <td>
                <xsl:value-of select="wf:NO_SUBSITES"/>
              </td>
            </tr>
            <tr>
              <th width="250">Station or associated water bodies located in a drinking water abstraction area*</th>
              <td>
                <xsl:call-template name="YesNoUnknown">
                  <xsl:with-param name="Param" select="wf:DRINK_WATER"/>
                </xsl:call-template>
              </td>
            </tr>
            <tr>
              <th width="250">Station is part of the Inter-calibration network.*</th>
              <td>
                <xsl:call-template name="YesNoUnknown">
                  <xsl:with-param name="Param" select="wf:INTERCAL_SITE"/>
                </xsl:call-template>
              </td>
            </tr>
            <tr>
              <th width="250">Unique code for the station in the Intercalibration network (if applicable)</th>
              <td>
                <xsl:value-of select="wf:INTERCAL_SITE_CD"/>
              </td>
            </tr>
            <tr>
              <th width="250">Station is part of a national network of reference sites.*</th>
              <td>
                <xsl:call-template name="YesNoUnknown">
                  <xsl:with-param name="Param" select="wf:REFERENCE_SITE"/>
                </xsl:call-template>
              </td>
            </tr>
            <tr>
              <th width="250">Unique code for the station in the reference network (if applicable)</th>
              <td>
                <xsl:value-of select="wf:REFERENCE_SITE_CD"/>
              </td>
            </tr>
            <tr>
              <th width="250">Brief description of any other networks that this station is a part of</th>
              <td>
                <xsl:value-of select="wf:OTHER_NETWORKS"/>
              </td>
            </tr>
            <tr>
              <th width="250">Hyperlink or reference to associated reference statement or file</th>
              <td>
                <xsl:value-of select="wf:ASSOC_DOC_REF"/>
              </td>
            </tr>
            <tr>
              <th width="250">URL to further information:</th>
              <td>
                <a>
                  <xsl:attribute name="href">
                    <xsl:value-of select="wf:URL"/>
                  </xsl:attribute>
                  <xsl:value-of select="wf:URL"/>
                </a>
              </td>
            </tr>
          </tbody>
        </table>
        <!-- now do the other networks -->
        <h4>International Networks</h4>
        <p>
          <span class="msg">International networks that this station is part of, if any</span>
        </p>
        <table>
          <tbody>
            <tr>
              <th>Name of the network</th>
              <th>Unique code for the station in this network</th>
            </tr>
            <xsl:for-each select="wf:INTER_NETWORKS/wf:INTER_NETWORK">
              <tr>
                <td>
                  <xsl:value-of select="wf:NAME"/>
                </td>
                <td>
                  <xsl:value-of select="wf:SITE_CD"/>
                </td>
              </tr>
            </xsl:for-each>
          </tbody>
        </table>
        <!-- now do the protected areas -->
        <h4>Protected Areas</h4>
        <p>
          <span class="msg">Type of protected area that the station or associated waterbodies is located in, if any.</span>
        </p>
        <xsl:apply-templates select="wf:PROT_AREAS"/>
        <!-- now the programme details -->
        <h4>Programmes</h4>
        <p>
          <span class="msg">This section describes the Article 8 programmes that the station is part of. The stations are linked to the programme using the code of the sub-programme. A station may be part of more than one programme</span>
        </p>
        <xsl:apply-templates select="wf:PROGRAMMES/wf:PROGRAMME"/>
      </div>
    </xsl:for-each>
  </xsl:template>
  <xsl:template match="wf:PROGRAMMES/wf:PROGRAMME">
    <h5>Programme: <xsl:value-of select="wf:SUB_CD"/></h5>
    <table>
      <tbody>
        <tr>
          <th width="250">EU code for sub-programme.</th>
          <td>
            <xsl:value-of select="wf:SUB_CD"/>
          </td>
        </tr>
        <tr>
          <th width="250"> Waterbodies monitored by this station</th>
          <td>
            <xsl:for-each select="wf:ASSOC_WB/wf:WB_CD">
              <xsl:if test="position() &gt; 1">, </xsl:if>
              <xsl:value-of select="."/>
            </xsl:for-each>
          </td>
        </tr>
      </tbody>
    </table>
    <h6>Quality elements measured at the station for this programme </h6>
    <p>
      <span class="msg">If this section is empty, then it is assumed that all quality elements defined in the programme are monitored for each associated waterbody.  </span>
    </p>
    <table>
      <tbody>
        <tr>
          <th>Quality Element Code*</th>
          <th>Surveillence</th>
          <th>Operational</th>
          <th>Subsites</th>
          <th>Frequency</th>
          <th>Cycle</th>
          <th>Cycle description</th>
          <th>Reason for deviation </th>
          <th>Waterbodies</th>
        </tr>
        <xsl:for-each select="wf:QUALITY_ELEMENTS/wf:QUALITY_ELEMENT">
          <tr>
            <td>
              <xsl:value-of select="wf:QE_CD"/>
            </td>
            <td>
              <xsl:call-template name="YesNoUnknown">
                <xsl:with-param name="Param" select="wf:SURVEIL"/>
              </xsl:call-template>
            </td>
            <td>
              <xsl:call-template name="YesNoUnknown">
                <xsl:with-param name="Param" select="wf:OPERAT"/>
              </xsl:call-template>
            </td>
            <td>
              <xsl:call-template name="SubsiteType">
                <xsl:with-param name="Param" select="wf:SUBSITES"/>
              </xsl:call-template>
            </td>
            <td>
              <xsl:value-of select="wf:FREQUENCY"/>
            </td>
            <td>
              <xsl:value-of select="wf:CYCLE"/>
            </td>
            <td>
              <xsl:value-of select="wf:CYCLE_DESCRIPTION"/>
            </td>
            <td>
              <xsl:value-of select="wf:REASON"/>
            </td>
            <td>
              <xsl:for-each select="wf:ASSOC_WB/wf:WB_CD">
                <xsl:if test="position() &gt; 1">, </xsl:if>
                <xsl:value-of select="."/>
              </xsl:for-each>
            </td>
          </tr>
        </xsl:for-each>
      </tbody>
    </table>
  </xsl:template>
  <xsl:template match="wf:PROT_AREAS">
    <table>
      <tbody>
        <tr>
          <th width="250">Station or associated water bodies located in an area protected under the Bathing Directive 76/160/EEC</th>
          <td>
            <xsl:call-template name="YesNoUnknown">
              <xsl:with-param name="Param" select="wf:BATHING"/>
            </xsl:call-template>
          </td>
        </tr>
        <tr>
          <th width="250">Station or associated water bodies located in an area protected under the Birds Directive 79/409/EEC</th>
          <td>
            <xsl:call-template name="YesNoUnknown">
              <xsl:with-param name="Param" select="wf:BIRDS"/>
            </xsl:call-template>
          </td>
        </tr>
        <tr>
          <th width="250">Station or associated water bodies located in an area protected under the Drinking Water Directive 80/778/EEC</th>
          <td>
            <xsl:call-template name="YesNoUnknown">
              <xsl:with-param name="Param" select="wf:DRINKING"/>
            </xsl:call-template>
          </td>
        </tr>
        <tr>
          <th width="250">Station or associated water bodies located in an area protected under the Fish Waters Directive 78/659/EEC</th>
          <td>
            <xsl:call-template name="YesNoUnknown">
              <xsl:with-param name="Param" select="wf:FISH"/>
            </xsl:call-template>
          </td>
        </tr>
        <tr>
          <th width="250">Station or associated water bodies located in an area protected under the Shellfish Waters Directive 79/923/EEC</th>
          <td>
            <xsl:call-template name="YesNoUnknown">
              <xsl:with-param name="Param" select="wf:SHELLFISH"/>
            </xsl:call-template>
          </td>
        </tr>
        <tr>
          <th width="250">Station or associated water bodies located in an area protected under the Habitats Directive 92/43/EEC</th>
          <td>
            <xsl:call-template name="YesNoUnknown">
              <xsl:with-param name="Param" select="wf:HABITATS"/>
            </xsl:call-template>
          </td>
        </tr>
        <tr>
          <th width="250">Station or associated water bodies located in an area protected under the Nitrates Directive 91/676/EEC</th>
          <td>
            <xsl:call-template name="YesNoUnknown">
              <xsl:with-param name="Param" select="wf:NITRATES"/>
            </xsl:call-template>
          </td>
        </tr>
        <tr>
          <th width="250">Station or associated water bodies located in an area protected under the Urban Waste Water Treatment Directive 91/271/EEC</th>
          <td>
            <xsl:call-template name="YesNoUnknown">
              <xsl:with-param name="Param" select="wf:UWWT"/>
            </xsl:call-template>
          </td>
        </tr>
        <tr>
          <th width="250">Station or associated water bodies located in an area protected the Directive concerning the quality required of surface water intended for the abstraction of drinking water 75/440/EEC</th>
          <td>
            <xsl:call-template name="YesNoUnknown">
              <xsl:with-param name="Param" select="wf:ABSTRACTION"/>
            </xsl:call-template>
          </td>
        </tr>
      </tbody>
    </table>
  </xsl:template>
  <xsl:template name="TableOfContents">
    <span class="indent1">
      <a href="#1">1. Surface Water Monitoring Stations Overview</a>
    </span>
    <br/>
    <span class="indent1">
      <a href="#2">2. Surface Water Monitoring Stations Details</a>
    </span>
    <br/>
  </xsl:template>
  <!-- Country implementation -->
  <xsl:template name="Country">
    <xsl:param name="MS"/>
    <xsl:choose>
      <xsl:when test="$MS='AT'">Austria</xsl:when>
      <xsl:when test="$MS='BE'">Belgium</xsl:when>
      <xsl:when test="$MS='BG'">Bulgaria</xsl:when>
      <xsl:when test="$MS='CH'">Switzerland</xsl:when>
      <xsl:when test="$MS='CY'">Cyprus</xsl:when>
      <xsl:when test="$MS='CZ'">Czech Republic</xsl:when>
      <xsl:when test="$MS='DE'">Germany</xsl:when>
      <xsl:when test="$MS='DK'">Denmark</xsl:when>
      <xsl:when test="$MS='EE'">Estonia</xsl:when>
      <xsl:when test="$MS='ES'">Spain</xsl:when>
      <xsl:when test="$MS='FI'">Finland</xsl:when>
      <xsl:when test="$MS='FR'">France</xsl:when>
      <xsl:when test="$MS='GR'">Greece</xsl:when>
      <xsl:when test="$MS='HU'">Hungary</xsl:when>
      <xsl:when test="$MS='IE'">Ireland</xsl:when>
      <xsl:when test="$MS='IS'">Iceland</xsl:when>
      <xsl:when test="$MS='IT'">Italy</xsl:when>
      <xsl:when test="$MS='LT'">Lithuania</xsl:when>
      <xsl:when test="$MS='LU'">Luxembourg</xsl:when>
      <xsl:when test="$MS='LV'">Latvia</xsl:when>
      <xsl:when test="$MS='MT'">Malta</xsl:when>
      <xsl:when test="$MS='NL'">The Netherlands</xsl:when>
      <xsl:when test="$MS='NO'">Norway</xsl:when>
      <xsl:when test="$MS='PL'">Poland</xsl:when>
      <xsl:when test="$MS='PT'">Portugal</xsl:when>
      <xsl:when test="$MS='RO'">Romania</xsl:when>
      <xsl:when test="$MS='SE'">Sweden</xsl:when>
      <xsl:when test="$MS='SI'">Slovenia</xsl:when>
      <xsl:when test="$MS='SK'">Slovakia</xsl:when>
      <xsl:when test="$MS='TR'">Turkey</xsl:when>
      <xsl:when test="$MS='UK'">United Kingdom</xsl:when>
    </xsl:choose>
  </xsl:template>
  <!-- Classification code implementation -->
  <xsl:template name="ClassificationCode">
    <xsl:param name="Param"/>
    <xsl:choose>
      <xsl:when test="$Param = '001'">Unclassified - available for general circulation</xsl:when>
      <xsl:when test="$Param = '003'">Confidential - available for EC reporting only</xsl:when>
    </xsl:choose>
  </xsl:template>
  <!-- YesNoUnknown implementation -->
  <xsl:template name="YesNoUnknown">
    <xsl:param name="Param"/>
    <xsl:choose>
      <xsl:when test="$Param = 'Y'">Yes</xsl:when>
      <xsl:when test="$Param = 'N'">No</xsl:when>
      <xsl:when test="$Param = 'U'">Unknown</xsl:when>
      <xsl:when test="$Param = 'NA'">Not Applicable</xsl:when>
    </xsl:choose>
  </xsl:template>
  <!-- WaterBodyCategory implementation -->
  <xsl:template name="WaterBodyCategory">
    <xsl:param name="Param"/>
    <xsl:choose>
      <xsl:when test="$Param = 'RW'">River</xsl:when>
      <xsl:when test="$Param = 'LW'">Lake</xsl:when>
      <xsl:when test="$Param = 'TW'">Transitional</xsl:when>
      <xsl:when test="$Param = 'CW'">Coastal</xsl:when>
    </xsl:choose>
  </xsl:template>
  <!-- Reporting Level implementation -->
  <xsl:template name="ReportingLevel">
    <xsl:param name="Param"/>
    <xsl:choose>
      <xsl:when test="$Param = 'I'">International RBD</xsl:when>
      <xsl:when test="$Param = 'N'">National part of an international RBD</xsl:when>
      <xsl:when test="$Param = 'R'">National RBD</xsl:when>
      <xsl:when test="$Param = 'S'">Regional part or sub-unit of RBD</xsl:when>
    </xsl:choose>
  </xsl:template>
  <!-- Programme Level implementation -->
  <xsl:template name="ProgrammeLevel">
    <xsl:param name="Param"/>
    <xsl:choose>
      <xsl:when test="$Param = 'I'">International</xsl:when>
      <xsl:when test="$Param = 'N'">National</xsl:when>
      <xsl:when test="$Param = 'R'">RBD</xsl:when>
    </xsl:choose>
  </xsl:template>
  <!-- Incident type implementation -->
  <xsl:template name="IncidentType">
    <xsl:param name="Param"/>
    <xsl:choose>
      <xsl:when test="$Param = 'E'">Unknown exceedence</xsl:when>
      <xsl:when test="$Param = 'F'">Failure of objectives</xsl:when>
      <xsl:when test="$Param = 'R'">Incident response</xsl:when>
      <xsl:when test="$Param = 'O'">Other</xsl:when>
    </xsl:choose>
  </xsl:template>
  <!-- Subsite type implementation -->
  <xsl:template name="SubsiteType">
    <xsl:param name="Param"/>
    <xsl:choose>
      <xsl:when test="$Param = 'A'">Area</xsl:when>
      <xsl:when test="$Param = 'T'">Transect</xsl:when>
      <xsl:when test="$Param = 'M'">Multipoint</xsl:when>
      <xsl:when test="$Param = 'N'">Not applicable/None</xsl:when>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>