View stylesheet

XML schemas http://dd.eionet.europa.eu/schemas/ippc-wi/ippc_module2_schema.xsd
Output type RDF
Description RDF
XSL file ippc_module2_rdf.xsl (Last modified: 09 Oct 2013 17:00 )
<?xml version="1.0" encoding="utf-8"?>
<!DOCTYPE xsl:stylesheet [
 <!ENTITY ippcns "http://rdfdata.eionet.europa.eu/ippc/ontology/">
 ]>

<!--
     XML Schema: http://dd.eionet.europa.eu/schemas/ippc-wi/ippc_module2_schema.xsd

     $Id: ippc_module2_rdf.xsl 15060 2013-10-09 14:59:54Z roug $ -->
<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
  xmlns:rdfs="http://www.w3.org/2000/01/rdf-schema#"
  xmlns="&ippcns;"
  version="1.0"
>

    <xsl:output method="xml" encoding="utf-8"/>

    <xsl:template match="text()"/>
    <xsl:template match="text()" mode="metals"/>
    <xsl:template match="text()" mode="ceramics"/>

    <xsl:template match="response">
        <rdf:RDF>
            <xsl:apply-templates/>
        </rdf:RDF>
    </xsl:template>

    <xsl:template match="installation">
      <xsl:if test="@type='metals-plastics' and normalize-space(q-1/q-1-2/q-1-2-1) != ''">
        <Installation>
         <xsl:attribute name="rdf:about">#<xsl:value-of select="normalize-space(q-1/q-1-2/q-1-2-1)"/></xsl:attribute>
           <type><xsl:value-of select="@type"/></type>
           <xsl:apply-templates mode="metals"/>
        </Installation>
      </xsl:if>
      <xsl:if test="@type='ceramics' and normalize-space(q-5/q-5-2/q-5-2-1) != ''">
        <Installation>
         <xsl:attribute name="rdf:about">#<xsl:value-of select="normalize-space(q-5/q-5-2/q-5-2-1)"/></xsl:attribute>
           <type><xsl:value-of select="@type"/></type>
           <xsl:apply-templates mode="ceramics"/>
        </Installation>
      </xsl:if>
    </xsl:template>


    <xsl:template match="q-1-1-1" mode="metals">
        <rdfs:label><xsl:value-of select="normalize-space(.)"/></rdfs:label>
        <name><xsl:value-of select="normalize-space(.)"/></name>
    </xsl:template>

    <xsl:template match="q-1-1-2" mode="metals">
        <address><xsl:value-of select="normalize-space(.)"/></address>
    </xsl:template>

    <xsl:template match="q-1-1-3" mode="metals">
        <country><xsl:value-of select="normalize-space(.)"/></country>
    </xsl:template>

    <xsl:template match="q-1-2-1" mode="metals">
        <prtrId><xsl:value-of select="normalize-space(.)"/></prtrId>
    </xsl:template>

    <xsl:template match="q-1-2-2" mode="metals">
        <xsl:if test="normalize-space(.) != ''">
            <permitLink><xsl:value-of select="normalize-space(.)"/></permitLink>
        </xsl:if>
    </xsl:template>

    <xsl:template match="q-5-1-1" mode="ceramics">
        <rdfs:label><xsl:value-of select="normalize-space(.)"/></rdfs:label>
        <name><xsl:value-of select="normalize-space(.)"/></name>
    </xsl:template>

    <xsl:template match="q-5-1-2" mode="ceramics">
        <address><xsl:value-of select="normalize-space(.)"/></address>
    </xsl:template>

    <xsl:template match="q-5-1-3" mode="ceramics">
        <country><xsl:value-of select="normalize-space(.)"/></country>
    </xsl:template>

    <xsl:template match="q-5-2-1" mode="ceramics">
        <prtrId><xsl:value-of select="normalize-space(.)"/></prtrId>
    </xsl:template>

    <xsl:template match="q-5-2-2" mode="ceramics">
        <xsl:if test="normalize-space(.) != ''">
            <permitLink><xsl:value-of select="normalize-space(.)"/></permitLink>
        </xsl:if>
    </xsl:template>

    <xsl:template match="*" mode="metals">
      <xsl:apply-templates mode="metals"/>
    </xsl:template>

    <xsl:template match="*" mode="ceramics">
      <xsl:apply-templates mode="ceramics"/>
    </xsl:template>

</xsl:stylesheet>