View stylesheet

XML schemas http://www.eionet.europa.eu/schemas/boundingboxes.xsd
Output type KML
Description Bounding boxes in KML format
XSL file stations-min-max-KML.xsl (Last modified: 30 Jan 2012 10:20 )
<?xml version="1.0" encoding="UTF-8"?>
<!--
      Generate KML 2.0
  -->
<xsl:stylesheet xmlns="http://earth.google.com/kml/2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
	<xsl:output method="xml" indent="yes" omit-xml-declaration="no"/>

	<xsl:template match="root">
		<kml xmlns="http://earth.google.com/kml/2.0">
			<Document>
				<name>Boundaries of EU countries </name>
				<description>Boundaries of EU countries for validating reported coordinates</description>
				<Style id="boundary">
					<IconStyle>
						<scale>1.0</scale>
						<Icon>
							<href>root://icons/palette-4.png</href>
							<x>32</x>
							<y>128</y>
							<w>32</w>
							<h>32</h>
						</Icon>
					</IconStyle>
					<LabelStyle>
						<scale>1.0</scale>
					</LabelStyle>
					<PolyStyle>
						<color>ff0000cc</color>
						<colorMode>normal</colorMode>
						<fill>0</fill>
					</PolyStyle>		 
					<LineStyle>
						<color>ff0000ff</color>
						<width>1</width>
					</LineStyle>      
				</Style>
				<xsl:apply-templates select="row">
					<xsl:sort select="ISO_2DIGIT"/>
				</xsl:apply-templates>
			</Document>
		</kml>
	</xsl:template>

	<xsl:template match="row">
		<Placemark>
			<name>
				<xsl:value-of select="ISO_2DIGIT"/>
			</name>
			<description>
				<xsl:value-of select="concat(MIN_CNTRY_, ': min=', minx, ', ', miny, '; max=', maxx, ', ', maxy)"/>
			</description>
			<open>0</open>
			<styleUrl>#boundary</styleUrl>
			<Polygon>
				<extrude>1</extrude>
				<altitudeMode>clampToGround</altitudeMode>
				<outerBoundaryIs>
					<LinearRing>
						<coordinates>
							<xsl:value-of select="minx"/>,<xsl:value-of select="miny"/>,0
							<xsl:value-of select="maxx"/>,<xsl:value-of select="miny"/>,0
							<xsl:value-of select="maxx"/>,<xsl:value-of select="maxy"/>,0
							<xsl:value-of select="minx"/>,<xsl:value-of select="maxy"/>,0
							<xsl:value-of select="minx"/>,<xsl:value-of select="miny"/>,0
						</coordinates>
					</LinearRing>
				</outerBoundaryIs>

				<coordinates><xsl:value-of select="minx"/>,<xsl:value-of select="miny"/></coordinates>
			</Polygon>
		</Placemark>
	</xsl:template>

	<xsl:template match="*">
		<xsl:value-of select="local-name()"/>: <xsl:value-of select="."/><xsl:text>&lt;br/&gt;</xsl:text>
	</xsl:template>

	<xsl:template match="MIN_CNTRY_" />

</xsl:stylesheet>