View stylesheet

XML schemas http://dd.sdr.edw.ro/GetSchema?id=TBL7212
Output type EXCEL
Description MS Excel
XSL file sdr-lakes-station-excel.xsl (Last modified: 13 Apr 2011 14:34 )
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:office="http://openoffice.org/2000/office" xmlns:table="http://openoffice.org/2000/table" xmlns:text="http://openoffice.org/2000/text" xmlns:dd715="http://dd.sdr.edw.ro/namespace.jsp?ns_id=715" xmlns:dd716="http://dd.sdr.edw.ro/namespace.jsp?ns_id=716">
	<xsl:template match="dd715:StationsLakes">
		<office:document-content office:version="1.0" xmlns:office="http://openoffice.org/2000/office" xmlns:table="http://openoffice.org/2000/table" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:number="http://openoffice.org/2000/datastyle" xmlns:text="http://openoffice.org/2000/text" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:style="http://openoffice.org/2000/style">
			<office:automatic-styles>
				<style:style style:name="cell1" style:family="table-cell">
					<style:properties fo:text-align="left" fo:font-size="10pt"/>
				</style:style>
				<style:style style:name="cell2" style:family="table-cell">
					<style:properties fo:text-align="center" fo:font-size="12pt" fo:font-style="italic"/>
				</style:style>
				<style:style style:name="Heading1" style:family="table-cell">
					<style:properties fo:text-align="left" fo:font-size="10pt" fo:font-style="italic" style:text-align-source="fix" fo:font-weight="bold"/>
				</style:style>
				<style:style style:name="Heading2" style:family="table-cell">
					<style:properties fo:text-align="center" fo:font-size="10pt" fo:font-weight="bold"/>
				</style:style>
			</office:automatic-styles>
			<office:body>
				<table:table>
					<xsl:attribute name="table:name">StationsLakes</xsl:attribute>
					<table:table-columns>
						<table:table-column table:default-cell-value-type="number" table:default-cell-style-name="cell1">
							<xsl:attribute name="table:number-columns-repeated">
								<xsl:value-of select="count(./dd715:Row[1]/*)"/>
							</xsl:attribute>
						</table:table-column>
					</table:table-columns><!-- create header rows -->
					<table:table-rows>
						<xsl:apply-templates select="dd715:Row"/>
					</table:table-rows>
				</table:table>
				<xsl:call-template name="DD_Schema_sheet"/>
			</office:body>
		</office:document-content>
	</xsl:template>
	<xsl:template match="dd715:Row">
		<xsl:if test="position()=1">
			<xsl:call-template name="header"/>
		</xsl:if>
		<table:table-row>
			<xsl:for-each select="*">
				<xsl:if test="count(preceding-sibling::*[local-name() = local-name(current())])=0">
					<table:table-cell xmlns:table="http://openoffice.org/2000/table">
						<text:p xmlns:text="http://openoffice.org/2000/text">
							<xsl:call-template name="getValue"/>
						</text:p>
					</table:table-cell>
				</xsl:if>
			</xsl:for-each>
		</table:table-row>
	</xsl:template><!--  a named template, which creates the table header row -->
	<xsl:template name="header">
		<table:table-header-rows><!--table:table-row   table:default-cell-value-type='string' table:default-cell-style-name='Heading1' >			<table:table-cell>				<text:p>Groundwater Body Characteristics and Pressures</text:p>			</table:table-cell>		</table:table-row-->
			<table:table-row table:default-cell-value-type="string" table:default-cell-style-name="Heading2">
				<xsl:for-each select="*">
					<xsl:if test="count(preceding-sibling::*[local-name() = local-name(current())])=0">
						<table:table-cell>
							<text:p>
								<xsl:value-of select="local-name()"/>
							</text:p>
						</table:table-cell>
					</xsl:if>
				</xsl:for-each>
			</table:table-row>
		</table:table-header-rows>
	</xsl:template><!-- Creates a sheet with XML schema, as it is done in DataDcit. Then it's possible to convert Excel back to XML-->
	<xsl:template name="DD_Schema_sheet">
		<table:table>
			<xsl:attribute name="table:name">DO_NOT_DELETE_THIS_SHEET</xsl:attribute>
			<table:table-columns>
				<table:table-column table:default-cell-value-type="text" table:default-cell-style-name="cell1"/>
			</table:table-columns>
			<table:table-rows>
				<table:table-row>
					<table:table-cell>
						<text:p>Please do not delete or modify this sheet!!!</text:p>
					</table:table-cell>
				</table:table-row>
				<table:table-row>
					<table:table-cell>
						<text:p>It is used for converting this file back to XML!</text:p>
					</table:table-cell>
				</table:table-row>
				<table:table-row>
					<table:table-cell>
						<text:p>Without this possibility your work cannot be used!</text:p>
					</table:table-cell>
				</table:table-row>
				<table:table-row>
					<table:table-cell>
						<text:p>http://dd.eionet.europa.eu/GetSchema?id=TBL4361</text:p>
					</table:table-cell>
				</table:table-row>
			</table:table-rows>
		</table:table>
	</xsl:template>
	<xsl:template name="getValue">
		<xsl:choose>
			<xsl:when test="count(following-sibling::*[local-name() = local-name(current())])=0">
				<xsl:value-of select="."/>
			</xsl:when>
			<xsl:otherwise>
				<xsl:call-template name="joinMultiValue">
					<xsl:with-param name="valueList" select="parent::*/child::*[local-name() = local-name(current())]"/>
				</xsl:call-template>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>
	<xsl:template name="joinMultiValue">
		<xsl:param name="valueList" select="''"/>
		<xsl:variable name="separator">
			<xsl:call-template name="getSeparator">
				<xsl:with-param name="element" select="local-name()"/>
			</xsl:call-template>
		</xsl:variable>
		<xsl:for-each select="$valueList">
			<xsl:choose>
				<xsl:when test="position() = 1">
					<xsl:value-of select="."/>
				</xsl:when>
				<xsl:otherwise>
					<xsl:value-of select="concat($separator, .)"/>
				</xsl:otherwise>
			</xsl:choose>
		</xsl:for-each>
	</xsl:template>
	<xsl:template name="getSeparator">
		<xsl:param name="element" select="''"/>
		<xsl:value-of select="','"/>
	</xsl:template>
</xsl:stylesheet>