Eionet
Conversion and Quality Assessment Service
View stylesheet
| XML schema |
http://bd.eionet.europa.eu/schemas/Art12Art17_reporting_2013/art12_generalreport.xsd
|
|---|---|
| Output type | HTML |
| Description | HTML Factsheet |
| XSL file | bgeneral.xsl (Last modified: 03 Nov 2013 17:55 ) |
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns="http://www.w3.org/1999/xhtml" xmlns:lookup="http://biodiversity.eionet.europa.eu/art12dataflow"
version="1.0" exclude-result-prefixes="xml lookup">
<xsl:import href="art12_redlist-common.xsl"/>
<xsl:variable name="report_type" select="'bgeneral'"/>
<xsl:output method="xml" indent="yes"
doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN" doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd"
omit-xml-declaration="yes" />
<xsl:param name="envelopeurl"/>
<xsl:param name="envelopepath"/>
<xsl:param name="filename"/>
<xsl:template match="birds_general_report">
<html>
<xsl:attribute name="xml:lang"><xsl:value-of select="@xml:lang"/></xsl:attribute>
<head>
<title>Factsheet</title>
<xsl:call-template name="getCss"/>
</head>
<body>
<h1>General report format, ref. Article 12 of the Birds Directive, for the 2008-2012 report</h1>
<table>
<tbody>
<xsl:apply-templates select="country"/>
</tbody>
</table>
<h2>1. Main achievements under the Birds Directive</h2>
<table>
<tbody>
<xsl:apply-templates select="achievements"/>
<xsl:apply-templates select="achievements_trans"/>
</tbody>
</table>
<h2>2. General information sources on the implementation of the Birds Directive - links to information sources of the Member State</h2>
<table>
<tbody>
<xsl:apply-templates select="general_information"/>
<xsl:apply-templates select="information_on_network"/>
<xsl:apply-templates select="monitoring_schemes"/>
<xsl:apply-templates select="protection_of_species"/>
<xsl:apply-templates select="transpose_directive"/>
</tbody>
</table>
<h2>3. SPA classification (Article 4)</h2>
<table>
<tbody>
<xsl:call-template name="spa"/>
</tbody>
</table>
<h2>4. Comprehensive management plans for SPAs</h2>
<table>
<tbody>
<xsl:apply-templates select="sites_with_plans"/>
<xsl:apply-templates select="coverage"/>
<xsl:apply-templates select="plans_under_prep"/>
</tbody>
</table>
<h2>5. Measures taken in relation to approval of plans and projects (Articles 6(4) and 7 of the Habitats Directive)</h2>
<xsl:apply-templates select="compensation_measures"/>
<h2>6. Research and work required as basis for the protection, management and use of bird populations (Article 10)</h2>
<table>
<tbody>
<tr><th colspan="3"><strong>6.1 National bird atlas</strong></th></tr>
<xsl:apply-templates select="national_bird_atlas_title"/>
<xsl:apply-templates select="national_bird_atlas_year"/>
<xsl:apply-templates select="national_bird_atlas_reference"/>
<tr><th colspan="3" style="padding-top:5px;"><strong>6.2 National bird monitoring overview</strong></th></tr>
<tr><td colspan="3"><xsl:apply-templates select="monitoring_publications"/></td></tr>
<tr><th colspan="3"><b>6.3 National bird red list</b></th></tr>
<xsl:apply-templates select="national_bird_redlist_title"/>
<xsl:apply-templates select="national_bird_redlist_year"/>
<xsl:apply-templates select="national_bird_redlist_reference"/>
<tr><th colspan="3"><b>6.4 Other publications of EU-wide interest (e.g. national overview of action for threatened species)</b></th></tr>
<tr><td colspan="3"><xsl:apply-templates select="other_publications"/></td></tr>
</tbody>
</table>
<h2>7. Non-native bird species (Article 11)</h2>
<xsl:apply-templates select="other_species"/>
</body>
</html>
</xsl:template>
<xsl:template name="spa">
<table>
<tr>
<th/>
<th>Number of SPAs</th>
<th>Surface area of SPAs (km<sup>2</sup>)</th>
</tr>
<tr>
<th>3.1 All SPAs</th>
<td>
<xsl:value-of select="spa_total_number"/>
</td>
<td>
<xsl:value-of select="spa_total_area"/>
</td>
</tr>
<tr>
<th>3.1.1 Terrestrial area of sites <br/> (excluding marine areas)</th>
<th/>
<td>
<xsl:value-of select="spa_terrestrial_area"/>
</td>
</tr>
<tr>
<th>3.1.2 Marine area of sites</th>
<td>
<xsl:value-of select="spa_marine_number"/>
</td>
<td>
<xsl:value-of select="spa_marine_area"/>
</td>
</tr>
<tr>
<th>3.2 Date of last update</th>
<td colspan="4">
<xsl:value-of select="database_date"/>
</td>
</tr>
</table>
</xsl:template>
<xsl:template match="compensation_measures">
<table>
<tr><th colspan="5">5.1 Project/plan with compensation measures</th></tr>
<tr>
<th>5.1.1 Site code</th>
<th>5.1.2 Site name</th>
<th>5.1.3 Year of project/plan</th>
<th>5.1.4 Title of project/plan</th>
<th>5.1.5 Impact of projects <span style="font-weight:normal">(optional)</span></th>
</tr>
<xsl:apply-templates/>
</table>
</xsl:template>
<xsl:template match="other_species">
<table>
<tr>
<th>7.1 Species scientific name</th>
<th>7.1.1 Sub-species</th>
<th>7.1.2 Main contents of legal decision for introduction</th>
<th>7.1.3 Consultation with the Commission </th>
</tr>
<xsl:apply-templates/>
</table>
</xsl:template>
<xsl:template match="other_publications|monitoring_publications">
<xsl:variable name="no">
<xsl:choose>
<xsl:when test="name(.) = 'monitoring_publications'">2</xsl:when>
<xsl:otherwise>4</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<table>
<tr>
<th>6.<xsl:value-of select="$no"/>.1 Title or similar plus short description</th>
<th>6.<xsl:value-of select="$no"/>.2 Year of publication</th>
<th>6.<xsl:value-of select="$no"/>.3 Web-link and/or bibliographic reference </th>
</tr>
<xsl:apply-templates/>
</table>
</xsl:template>
<xsl:template match="measure">
<tr>
<td>
<xsl:value-of select="sitecode"/>
</td>
<td>
<xsl:value-of select="sitename"/>
</td>
<td>
<xsl:value-of select="project_year"/>
</td>
<td>
<xsl:call-template name="break">
<xsl:with-param name="text" select="project_title"/>
</xsl:call-template>
</td>
<td>
<xsl:call-template name="break">
<xsl:with-param name="text" select="impact"/>
</xsl:call-template>
</td>
</tr>
</xsl:template>
<xsl:template match="species">
<tr>
<xsl:apply-templates/>
</tr>
</xsl:template>
<xsl:template match="publication">
<tr>
<td>
<xsl:call-template name="break">
<xsl:with-param name="text" select="title"/>
</xsl:call-template>
</td>
<td>
<xsl:value-of select="year"/>
</td>
<td>
<xsl:call-template name="break">
<xsl:with-param name="text" select="reference"/>
</xsl:call-template>
</td>
</tr>
</xsl:template>
<xsl:template match="achievements|achievements_trans|additional_information|general_information|information_on_network|monitoring_schemes|protection_of_species|transpose_directive">
<tr>
<th>
<xsl:call-template name="tag-label">
<xsl:with-param name="tagname" select="name(.)"/>
</xsl:call-template>
</th>
<td class="preserve" colspan="2">
<xsl:if test="string-length(.)=0">
</xsl:if>
<xsl:if test="string-length(.)!=0">
<xsl:call-template name="break">
<xsl:with-param name="text" select="."/>
</xsl:call-template>
</xsl:if>
</td>
</tr>
</xsl:template>
<xsl:template match="speciesname|subspecies_name|introduction|consultation_date">
<td class="preserve">
<xsl:if test="string-length(.)=0">
</xsl:if>
<xsl:if test="string-length(.)!=0">
<xsl:call-template name="break">
<xsl:with-param name="text" select="."/>
</xsl:call-template>
</xsl:if>
</td>
</xsl:template>
</xsl:stylesheet>