View stylesheet

XML schema http://converters.eionet.europa.eu/schema/schema-335.xsd
Output type HTML
Description HTML report
XSL file df6_9-noise-control-old-schema.xsl (Last modified: 10 Aug 2012 12:44 )
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns="http://www.w3.org/1999/xhtml"
                version="1.0">
    <xsl:output method="xml" indent="yes"
              doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN"
              doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd"
              omit-xml-declaration="yes" encoding="UTF-8"/>


    <xsl:template match="/">
        <html>
            <head>
                <title>Noise control programmes (DF 6 and DF 9)</title>
                <meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
                <style type="text/css">
        ul {list-style-type: none; margin: 0; padding: 0}
        span.lbl {float: right; font-weight: bold; text-align: right; padding-right: 3px; width: 100%}
        table.list{
            border-collapse:collapse;
        }
        table.list td, th{
            border:1px solid black;
        }
        .lbl2{
            font-weight:bold;
            padding:3px;
        }
            </style>
            </head>
            <body>
                <h1>Noise control programmes (DF 6 and DF 9)</h1>
                <table class="list">
                        <tr>
                            <th>Name of DF_6_9</th>
                            <th>Unique code</th>
                            <th>Reporting issue</th>
                            <th>Reporting issue ID</th>
                            <th>Cost (in €)</th>
                            <th>Adoption date</th>
                            <th>Completion date</th>
                        </tr>
                    <xsl:for-each select="NoiseDirective_DF6_9/NoiseControlProgramme">
                        <tr>
                            <td>
                                <a>
                                    <xsl:attribute name="href">#<xsl:value-of select="position()"/></xsl:attribute>
                                    <xsl:value-of select="NameOfNoiseControlProgramme"/>
                                </a>
                            </td>
                            <td>
                                <xsl:value-of select="ReportingEntityUniqueCode"/>
                            </td>
                            <td>
                                <xsl:call-template name="getReportingIssueTypeName">
                                    <xsl:with-param name="type">
                                        <xsl:value-of select="ReportingIssue/@type"/>
                                    </xsl:with-param>
                                </xsl:call-template>
                            </td>
                            <td>
                                <xsl:apply-templates select="ReportingIssue"/>
                            </td>
                            <td>
                                <xsl:value-of select="CostOfProgramme"/>
                            </td>
                            <td>
                                <xsl:choose>
                                    <xsl:when test="DateOfAdoption/@notavailable='true'">Not available</xsl:when>
                                    <xsl:otherwise><xsl:value-of select="DateOfAdoption"/></xsl:otherwise>
                                </xsl:choose>
                            </td>
                            <td>
                                <xsl:choose>
                                    <xsl:when test="DateOfCompletion/@notavailable='true'">Not available</xsl:when>
                                    <xsl:otherwise><xsl:value-of select="DateOfCompletion"/></xsl:otherwise>
                                </xsl:choose>
                            </td>
                        </tr>
                </xsl:for-each>
                </table>

                <xsl:for-each select="NoiseDirective_DF6_9/NoiseControlProgramme">
                    <div>
                        <a>
                            <xsl:attribute name="name"><xsl:value-of select="position()"/></xsl:attribute>
                        </a>
                        <h3> Name of DF_6_9: <xsl:value-of select="NameOfNoiseControlProgramme"/></h3>
                    </div>
                    <div style="padding-bottom: 7px; border: 1px solid black">
                        <table border="0" cellspacing="1">
                            <tr>
                                <td>
                                    <span class="lbl">Full name of Noise Control Programme summary report</span>
                                </td>
                                <td>
                                    <xsl:value-of select="FullNameOfProgramme"/>
                                </td>
                            </tr>
                            <tr>
                                <td>
                                    <span class="lbl">Reporting entity unique code</span>
                                </td>
                                <td>
                                    <xsl:value-of select="ReportingEntityUniqueCode"/>
                                </td>
                            </tr>
                            <tr>
                                <td>
                                    <span class="lbl">Reporting issue</span>
                                </td>
                                <td>
                                    <xsl:call-template name="getReportingIssueTypeName">
                                        <xsl:with-param name="type">
                                            <xsl:value-of select="ReportingIssue/@type"/>
                                        </xsl:with-param>
                                    </xsl:call-template>
                                </td>
                            </tr>
                            <tr>
                                <td>
                                    <span class="lbl">Reporting a noise control programme for </span>
                                </td>
                                <td>
                                    <xsl:apply-templates select="ReportingIssue"/>
                                </td>
                            </tr>
                            <tr>
                                <td>
                                    <span class="lbl">Cost (in €)</span>
                                </td>
                                <td>
                                    <xsl:value-of select="CostOfProgramme"/>
                                </td>
                            </tr>
                            <tr>
                                <td>
                                    <span class="lbl">Adoption date</span>
                                </td>
                                <td>
                                    <xsl:choose>
                                        <xsl:when test="DateOfAdoption/@notavailable='true'">Not available</xsl:when>
                                        <xsl:otherwise><xsl:value-of select="DateOfAdoption"/></xsl:otherwise>
                                    </xsl:choose>
                                </td>
                            </tr>
                            <tr>
                                <td>
                                    <span class="lbl">Completion date</span>
                                </td>
                                <td>
                                    <xsl:choose>
                                        <xsl:when test="DateOfCompletion/@notavailable='true'">Not available</xsl:when>
                                        <xsl:otherwise><xsl:value-of select="DateOfCompletion"/></xsl:otherwise>
                                    </xsl:choose>
                                </td>
                            </tr>
                            <tr>
                                <td>
                                    <span class="lbl">Number of people experiencing noise reduction</span>
                                </td>
                                <td>
                                    <xsl:value-of select="NofPeopleExperiencingNoiseReduction"/>
                                </td>
                            </tr>
                        </table>
                        <p class="lbl2">Limit values in place at the time of adoption of the noise control programme (preferably converted where relevant in Lden, Lday, Levening, Lnight as defined by Annex I of the Directive 2002/49/EC)</p>
                        <p class="val2">
                            <xsl:value-of select="LimitValues"/>
                        </p>
                        <p class="lbl2">Summary of the main problems to be solved and of the situations that needed to be improved at that time</p>
                        <p class="val2">
                            <xsl:value-of select="SummaryOfProblems"/>
                        </p>
                        <p class="lbl2">Summary of the results of public consultations organized in relation to this noise control programme</p>
                        <p class="val2">
                            <xsl:value-of select="SummaryOfResults"/>
                        </p>
                        <p class="lbl2">Summary of noise management actions (and related budget and targets) taken</p>
                        <p class="val2">
                            <xsl:value-of select="SummaryOfActions"/>
                        </p>
                        <p class="lbl2">Summary of provisions used for evaluating the implementation and results of the noise control programme</p>
                        <p class="val2">
                            <xsl:value-of select="SummaryOfProvisions"/>
                        </p>
                        <p class="lbl2">Web links to the full noise control programme</p>
                        <p class="val2">
                            <xsl:value-of select="WebLinks"/>
                        </p>
                    </div>
                </xsl:for-each>
            </body>
        </html>
    </xsl:template>
    <xsl:template name="getReportingIssueTypeName">
        <xsl:param name="type"/>
        <xsl:choose>
            <xsl:when test="$type='agg'">Agglomeration</xsl:when>
            <xsl:when test="$type='road'">Roads</xsl:when>
            <xsl:when test="$type='rail'">Railways</xsl:when>
            <xsl:when test="$type='air'">Airport</xsl:when>
        </xsl:choose>
    </xsl:template>
    <!--
    Display reporting entity name or ID
    -->
    <xsl:template match="ReportingIssue">
        <xsl:choose>
            <xsl:when test="@type='agg'">
                <xsl:choose>
                    <xsl:when test="@entireEntity='true'">entire entity</xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="concat('UniqueAgglomerationId= ', UniqueAgglomerationId)"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:when>
            <xsl:when test="@type='road'">
                <xsl:choose>
                    <xsl:when test="@entireEntity='true'">entire entity</xsl:when>
                    <xsl:otherwise>
                        <xsl:if test="string-length(normalize-space(PartialArea)) > 0"><xsl:value-of select="concat('PartialArea= ', PartialArea, '; ')"/></xsl:if>
                        <xsl:if test="string-length(normalize-space(UniqueRoadId)) > 0"><xsl:value-of select="concat('UniqueueRoadID= ', UniqueRoadId)"/></xsl:if>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:when>
            <xsl:when test="@type='rail'">
                <xsl:choose>
                    <xsl:when test="@entireEntity='true'">entire entity</xsl:when>
                    <xsl:otherwise>
                        <xsl:if test="string-length(normalize-space(PartialArea)) > 0"><xsl:value-of select="concat('PartialArea= ', PartialArea, '; ')"/></xsl:if>
                        <xsl:if test="string-length(normalize-space(UniqueRailId)) > 0"><xsl:value-of select="concat('UniqueRailId= ', UniqueRailId)"/></xsl:if>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:when>
            <xsl:when test="@type='air'">
                <xsl:choose>
                    <xsl:when test="@entireEntity='true'">entire entity</xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="concat('ICAO code= ',IcaoCode)"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:when>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>